Previous | Contents | Next

## 4.9 Instructions

### 4.9.1 Basic Instructions

The instructions that NSIS uses for scripting are sort of a cross between PHP and assembly. There are no real high level language constructs, but the instructions themselves are (for the most part) high level, and you have handy string capability (i.e. you don't have to worry about concatenating strings, etc). You essentially have 25 registers (20 general purpose, 5 special purpose), and a stack.

#### 4.9.1.1 Delete

    [/REBOOTOK] file

Delete file (which can be a file or wildcard, but should be specified with a full path) from the target system. If /REBOOTOK is specified and the file cannot be deleted then the file is deleted when the system reboots -- if the file will be deleted on a reboot, the reboot flag will be set. The error flag is set if files are found and cannot be deleted. The error flag is not set from trying to delete a file that does not exist.

    Delete $INSTDIR\somefile.dat

#### 4.9.1.2 Exec

    command

Execute the specified program and continue immediately. Note that the file specified must exist on the target system, not the compiling system. $OUTDIR is used for the working directory. The error flag is set if the process could not be launched. Note, if the command could have spaces, you should put it in quotes to delimit it from parameters. e.g.: Exec '"$INSTDIR\command.exe" parameters'. If you don't put it in quotes it will not work on Windows 9x with or without parameters.

    Exec '"$INSTDIR\someprogram.exe"'

    Exec '"$INSTDIR\someprogram.exe" some parameters'

#### 4.9.1.3 ExecShell

    action command [parameters] [SW_SHOWNORMAL | SW_SHOWMAXIMIZED | SW_SHOWMINIMIZED | SW_HIDE]

Execute the specified program using ShellExecute. Note that action is usually "open", "print", etc, but can be an empty string to use the default action. Parameters and the show type are optional. $OUTDIR is used for the working directory. The error flag is set if the process could not be launched.

    ExecShell "open" "http://nsis.sf.net/"

    ExecShell "open" "$INSTDIR\readme.txt"

    ExecShell "print" "$INSTDIR\readme.txt"

#### 4.9.1.4 ExecWait

    command [user_var(exit code)]

Execute the specified program and wait for the executed process to quit. See Exec for more information. If no output variable is specified ExecWait sets the error flag if the program executed returns a nonzero error code, or if there is an error. If an output variable is specified, ExecWait sets the variable with the exit code (and only sets the error flag if an error occurs; if an error occurs the contents of the user variable are undefined). Note, if the command could have spaces, you should put it in quotes to delimit it from parameters. e.g.: ExecWait '"$INSTDIR\command.exe" parameters'. If you don't put it in quotes it will not work on Windows 9x with or without parameters.

    ExecWait '"$INSTDIR\someprogram.exe"'

    ExecWait '"$INSTDIR\someprogram.exe"' $0

    DetailPrint "some program returned $0"

#### 4.9.1.5 File

    [/nonfatal] [/a] ([/r] [/x file|wildcard [...]] (file|wildcard) [...] | /oname=file.dat infile.dat)

Adds file(s) to be extracted to the current output path ($OUTDIR).

- Note that the output file name is $OUTDIR\filename_portion_of_file.
- If the /oname=X switch is used, the output name becomes $OUTDIR\X. When using the /oname= switch, only one file can be specified, and the file name can contain variables (or a fully qualified path, e.g. $SYSDIR\whatever.dll). If the output name contains spaces, quote the entire parameter, including /oname, as shown in the examples below.
- Wildcards are supported.
- If the /r switch is used, matching files and directories are recursively searched for in subdirectories. If just one path segment is specified (e.g. `File /r something`), the current directory will be recursively searched. If more than one segment is specified (e.g. `File /r something\*.*`), the last path segment will be used as the matching condition and the rest for the directory to search recursively. If a directory name matches, all of its contents is added recursively. Directory structure is preserved.
- Use the /x switch to exclude files or directories.
- If the /a switch is used, the attributes of the file(s) added will be preserved.
- The File command sets the error flag if overwrite mode is set to 'try' and the file could not be overwritten, or if the overwrite mode is set to 'on' and the file could not be overwritten and the user selects ignore.
- If the /nonfatal switch is used and no files are found, a warning will be issued instead of an error.

    File something.exe

    File /a something.exe

    File *.exe

    File /r *.dat

    File /r data

    File /oname=$TEMP\temp.dat somefile.ext

    File "/oname=$TEMP\name with spaces.dat" somefile.ext

    File /nonfatal "a file that might not exist"

    File /r /x CVS myproject\*.*

    File /r /x *.res /x *.obj /x *.pch source\*.*

Note: when using the /r switch, both matching directories and files will be searched. This is always done with or without the use of wildcards, even if the given path perfectly matches one directory. That means, the following directory structure:

    <DIR> something

      file.dat

      another.dat

    <DIR> dir

      something

      <DIR> dir2

        file2.dat

    <DIR> another

      <DIR> something

        readme.txt

with the following File usage:

    File /r something

will match the directory named something on the root directory, the file named something in the directory named dir and the directory named something in the directory named another. To match only the directory named something on the root directory, use the following:

    File /r something\*.*

When adding \*.*, it will be used as the matching condition and something will be used as the directory to search. When only something is specified, the current directory will be recursively searched for every and directory named something and another\something will be matched.

#### 4.9.1.6 Rename

    [/REBOOTOK] source_file dest_file

Rename source_file to dest_file. You can use it to move a file from anywhere on the system to anywhere else and you can move a directory to somewhere else on the same drive. The destination file must not exist or the move will fail (unless you are using /REBOOTOK). If /REBOOTOK is specified, and the file cannot be moved (if, for example, the destination exists), then the file is moved when the system reboots. If the file will be moved on a reboot, the reboot flag will be set. The error flag is set if the file cannot be renamed (and /REBOOTOK is not used) or if the source file does not exist.

If no absolute path is specified the current folder will be used. The current folder is the folder set using the last SetOutPath instruction. If you have not used SetOutPath the current folder is $EXEDIR.

    Rename $INSTDIR\file.ext $INSTDIR\file.dat

#### 4.9.1.7 ReserveFile

    [/nonfatal] [/r] [/x file|wildcard [...]] file [file...]

Reserves a file in the data block for later use. Files are added to the compressed data block in the order they appear in the script. Functions, however, are not necessarily called in the order they appear in the script. Therefore, if you add a file in a function called early but put the function at the end of the script, all of the files added earlier will have to be decompressed to get to the required file. This process can take a long time if there a lot of files. .onInit is one such function. It is called at the very beginning, before anything else appears. If you put it at the very end of the script, extract some files in it and have lots of files added before it, the installer might take a very long time to load. This is where this command comes useful, allowing you to speed up the loading process by including the file at the top of the data block instead of letting NSIS seek all the way down to the bottom of the compressed data block.

See File for more information about the parameters.

#### 4.9.1.8 RMDir

    [/r] [/REBOOTOK] directory_name

Remove the specified directory (fully qualified path with no wildcards). Without /r, the directory will only be removed if it is completely empty. If /r is specified, the directory will be removed recursively, so all directories and files in the specified directory will be removed. If /REBOOTOK is specified, any file or directory which could not have been removed during the process will be removed on reboot -- if any file or directory will be removed on a reboot, the reboot flag will be set. The error flag is set if any file or directory cannot be removed.

    RMDir $INSTDIR

    RMDir $INSTDIR\data

    RMDir /r /REBOOTOK $INSTDIR

    RMDir /REBOOTOK $INSTDIR\DLLs

Note that the current working directory can not be deleted. The current working directory is set by SetOutPath. For example, the following example will not delete the directory.

    SetOutPath $TEMP\dir

    RMDir $TEMP\dir

The next example will succeed in deleting the directory.

    SetOutPath $TEMP\dir

    SetOutPath $TEMP

    RMDir $TEMP\dir

Warning: using RMDir /r $INSTDIR in the uninstaller is not safe. Though it is unlikely, the user might select to install to the Program Files folder and so this command will wipe out the entire Program Files folder, including other programs that has nothing to do with the uninstaller. The user can also put other files but the program's files and would expect them to get deleted with the program. Solutions are available for easily uninstalling only files which were installed by the installer.

#### 4.9.1.9 SetOutPath

    outpath

Sets the output path ($OUTDIR) and creates it (recursively if necessary), if it does not exist. Must be a full pathname, usually is just $INSTDIR (you can specify $INSTDIR if you are lazy with a single "-").

    SetOutPath $INSTDIR

    File program.exe

### 4.9.2 Registry, INI, File Instructions

In all of the below registry instructions use an empty string (just two quotes with nothing between them - "") as the key name to specify the default key which is shown as (Default) in regedit.exe.

If a full path is not specified for any of the INI handling instructions, the Windows directory will be used.

#### 4.9.2.1 DeleteINISec

    ini_filename section_name

Deletes the entire section [section_name] from ini_filename. If the section could not be removed from the ini file, the error flag is set. It does not set the error flag if the section could not be found.

    WriteINIStr $TEMP\something.ini section1 something 123

    WriteINIStr $TEMP\something.ini section1 somethingelse 1234

    WriteINIStr $TEMP\something.ini section2 nsis true

    DeleteINISec $TEMP\something.ini section1

#### 4.9.2.2 DeleteINIStr

    ini_filename section_name str_name

Deletes the string str_name from section [section_name] from ini_filename. If the string could not be removed from the ini file, the error flag is set. It does not set the error flag if the string could not be found.

    WriteINIStr $TEMP\something.ini section1 something 123

    WriteINIStr $TEMP\something.ini section1 somethingelse 1234

    DeleteINIStr $TEMP\something.ini section1 somethingelse

#### 4.9.2.3 DeleteRegKey

    [/ifempty] root_key subkey

Deletes a registry key. If /ifempty is specified, the registry key will only be deleted if it has no subkeys (otherwise, the whole registry tree will be removed). Valid values for root_key are listed under WriteRegStr. The error flag is set if the key could not be removed from the registry (or if it didn't exist to begin with).

    DeleteRegKey HKLM "Software\My Company\My Software"

    DeleteRegKey /ifempty HKLM "Software\A key that might have subkeys"

#### 4.9.2.4 DeleteRegValue

    root_key subkey key_name

Deletes a registry value. Valid values for root_key are listed under WriteRegStr. The error flag is set if the value could not be removed from the registry (or if it didn't exist to begin with).

    DeleteRegValue HKLM "Software\My Company\My Software" "some value"

#### 4.9.2.5 EnumRegKey

    user_var(output) root_key subkey index

Set user variable $x with the name of the 'index'th registry key in root_key\Subkey. Valid values for root_key are listed under WriteRegStr. Returns an empty string if there are no more keys, and returns an empty string and sets the error flag if there is an error.

    StrCpy $0 0

    loop:

      EnumRegKey $1 HKLM Software $0

      StrCmp $1 "" done

      IntOp $0 $0 + 1

      MessageBox MB_YESNO|MB_ICONQUESTION "$1$\n$\nMore?" IDYES loop

    done:

#### 4.9.2.6 EnumRegValue

    user_var(output) root_key subkey index

Set user variable $x with the name of the 'index'th registry value in root_key\Subkey. Valid values for root_key are listed under WriteRegStr. Returns an empty string and sets the error flag if there are no more values or if there is an error.

    StrCpy $0 0

    loop:

      ClearErrors

      EnumRegValue $1 HKLM Software\Microsoft\Windows\CurrentVersion $0

      IfErrors done

      IntOp $0 $0 + 1

      ReadRegStr $2 HKLM Software\Microsoft\Windows\CurrentVersion $1

      MessageBox MB_YESNO|MB_ICONQUESTION "$1 = $2$\n$\nMore?" IDYES loop

    done:

#### 4.9.2.7 ExpandEnvStrings

    user_var(output) string

Expands environment variables in string into the user variable $x. If an environment variable doesn't exist, it will not be replaced. For example, if you use "%var%" and var doesn't exists, the result will be "%var". If there is an error, the variable is set to empty, and the error flag is set.

    ExpandEnvStrings $0 "WINDIR=%WINDIR%$\nTEMP=%TEMP%"

#### 4.9.2.8 FlushINI

    ini_filename

Flushes the INI file's buffers. Windows 9x keeps all changes to the INI file in memory. This command causes the changes to be written to the disk immediately. Use it if you edit the INI manually, delete it, move it or copy it right after you change it with WriteINIStr, DeleteINISec or DeleteINStr.

    WriteINIStr $TEMP\something.ini test test test

    FlushINI $TEMP\something.ini

    Delete $TEMP\something.ini

#### 4.9.2.9 ReadEnvStr

    user_var(output) name

Reads from the environment string "name" and sets the value into the user variable $x. If there is an error reading the string, the user variable is set to empty, and the error flag is set.

    ReadEnvStr $0 WINDIR

    ReadEnvStr $1 TEMP

#### 4.9.2.10 ReadINIStr

    user_var(output) ini_filename section_name entry_name

Reads from entry_name in [section_name] of ini_filename and stores the value into user variable $x. The error flag will be set and $x will be assigned to an empty string if the entry is not found.

    ReadINIStr $0 $INSTDIR\winamp.ini winamp outname

#### 4.9.2.11 ReadRegDWORD

    user_var(output) root_key sub_key name

Reads a 32 bit DWORD from the registry into the user variable $x. Valid values for root_key are listed under WriteRegStr. The error flag will be set and $x will be set to an empty string ("" which is 0) if the DWORD is not present. If the value is present, but is not a DWORD, it will be read as a string and the error flag will be set.

    ReadRegDWORD $0 HKLM Software\NSIS VersionBuild

#### 4.9.2.12 ReadRegStr

    user_var(output) root_key sub_key name

Reads from the registry into the user variable $x. Valid values for root_key are listed under WriteRegStr. The error flag will be set and $x will be set to an empty string ("") if the string is not present. If the value is present, but is of type REG_DWORD, it will be read and converted to a string and the error flag will be set.

    ReadRegStr $0 HKLM Software\NSIS ""

    DetailPrint "NSIS is installed at: $0"

#### 4.9.2.13 WriteINIStr

    ini_filename section_name entry_name value

Writes entry_name=value into [section_name] of ini_filename. The error flag is set if the string could not be written to the ini file.

    WriteINIStr $TEMP\something.ini section1 something 123

    WriteINIStr $TEMP\something.ini section1 somethingelse 1234

    WriteINIStr $TEMP\something.ini section2 nsis true

#### 4.9.2.14 WriteRegBin

    root_key subkey key_name valuedata

This command writes a block of binary data to the registry. Valid values for root_key are listed under WriteRegStr. Valuedata is in hexadecimal (e.g. DEADBEEF01223211151). The error flag is set if the binary data could not be written to the registry. If the registry key doesn't exist it will be created.

    WriteRegBin HKLM "Software\My Company\My Software" "Binary Value" DEADBEEF01223211151

#### 4.9.2.15 WriteRegDWORD

    root_key subkey key_name value

This command writes a dword (32 bit integer) to the registry (a user variable can be specified). Valid values for root_key are listed under WriteRegStr. The error flag is set if the dword could not be written to the registry. If the registry key doesn't exist it will be created.

    WriteRegDWORD HKLM "Software\My Company\My Software" "DWORD Value" 0xDEADBEEF

#### 4.9.2.16 WriteRegStr

    root_key subkey key_name value

Write a string to the registry. See WriteRegExpandStr for more details.

    WriteRegStr HKLM "Software\My Company\My Software" "String Value" "dead beef"

#### 4.9.2.17 WriteRegExpandStr

    root_key subkey key_name value

Write a string to the registry. root_key must be one of:

- HKCR or HKEY_CLASSES_ROOT
- HKLM or HKEY_LOCAL_MACHINE
- HKCU or HKEY_CURRENT_USER
- HKU or HKEY_USERS
- HKCC or HKEY_CURRENT_CONFIG
- HKDD or HKEY_DYN_DATA
- HKPD or HKEY_PERFORMANCE_DATA
- SHCTX or SHELL_CONTEXT

If root_key is SHCTX or SHELL_CONTEXT, it will be replaced with HKLM if SetShellVarContext is set to all and with HKCU if SetShellVarContext is set to current.

The error flag is set if the string could not be written to the registry. The type of the string will be REG_SZ for WriteRegStr, or REG_EXPAND_STR for WriteRegExpandStr. If the registry key doesn't exist it will be created.

    WriteRegExpandStr HKLM "Software\My Company\My Software" "Expand String Value" "%WINDIR%\notepad.exe"

### 4.9.3 General Purpose Instructions

#### 4.9.3.1 CallInstDLL

    dllfile [/NOUNLOAD] function_name

Calls a function named function_name inside a NSIS extension DLL, a plug-in. See the example plugin for how to make one. Extension DLLs can access the stack and variables. Use /NOUNLOAD to force the installer to leave the DLL loaded. Note: To automatically extract and call plug-in DLLs, use a plug-in command instead of CallInstDLL.

    Push "a parameter"

    Push "another parameter"

    CallInstDLL $INSTDIR\somedll.dll somefunction

For easier plug-in handling, use the new plug-in call syntax.

#### 4.9.3.2 CopyFiles

    [/SILENT] [/FILESONLY] filespec_on_destsys destination_path [size_of_files_in_kb]

Copies files from the source to the destination on the installing system. Useful with $EXEDIR if you want to copy from installation media, or to copy from one place to another on the system. You might see a Windows status window of the copy operation if the operation takes a lot of time (to disable this, use /SILENT). The last parameter can be used to specify the size of the files that will be copied (in kilobytes), so that the installer can approximate the disk space requirements. On error, or if the user cancels the copy (only possible when /SILENT was omitted), the error flag is set. If /FILESONLY is specified, only files are copied.

Fully-qualified path names should always be used with this instruction. Using relative paths will have unpredictable results.

    CreateDirectory $INSTDIR\backup

    CopyFiles $INSTDIR\*.dat $INSTDIR\backup

#### 4.9.3.3 CreateDirectory

    path_to_create

Creates (recursively if necessary) the specified directory. The error flag is set if the directory couldn't be created.

You should always specify an absolute path.

    CreateDirectory $INSTDIR\some\directory

#### 4.9.3.4 CreateShortCut

    link.lnk target.file [parameters [icon.file [icon_index_number [start_options [keyboard_shortcut [description]]]]]]

Creates a shortcut 'link.lnk' that links to 'target.file', with optional parameters 'parameters'. The icon used for the shortcut is 'icon.file,icon_index_number'; for default icon settings use empty strings for both icon.file and icon_index_number. start_options should be one of: SW_SHOWNORMAL, SW_SHOWMAXIMIZED, SW_SHOWMINIMIZED, or an empty string. keyboard_shortcut should be in the form of 'flag|c' where flag can be a combination (using |) of: ALT, CONTROL, EXT, or SHIFT. c is the character to use (a-z, A-Z, 0-9, F1-F24, etc). Note that no spaces are allowed in this string. A good example is "ALT|CONTROL|F8". $OUTDIR is used for the working directory. You can change it by using SetOutPath before creating the Shortcut. description should be the description of the shortcut, or comment as it is called under XP. The error flag is set if the shortcut cannot be created (i.e. either of the paths (link or target) does not exist, or some other error).

    CreateDirectory "$SMPROGRAMS\My Company"

    CreateShortCut "$SMPROGRAMS\My Company\My Program.lnk" "$INSTDIR\My Program.exe" \

      "some command line parameters" "$INSTDIR\My Program.exe" 2 SW_SHOWNORMAL \

      ALT|CTRL|SHIFT|F5 "a description"

#### 4.9.3.5 GetDLLVersion

    filename user_var(high dword output) user_var(low dword output)

Gets the version information from the DLL (or any other executable containing version information) in "filename". Sets the user output variables with the high and low dwords of version information on success; on failure the outputs are empty and the error flag is set. The following example reads the DLL version and copies a human readable version of it into $0:

    GetDllVersion "$INSTDIR\MyDLL.dll" $R0 $R1

    IntOp $R2 $R0 / 0x00010000

    IntOp $R3 $R0 & 0x0000FFFF

    IntOp $R4 $R1 / 0x00010000

    IntOp $R5 $R1 & 0x0000FFFF

    StrCpy $0 "$R2.$R3.$R4.$R5"

#### 4.9.3.6 GetDLLVersionLocal

    localfilename user_var(high dword output) user_var(low dword output)

This is similar to GetDLLVersion, only it acts on the system building the installer (it actually compiles into two StrCpy commands). Sets the two output variables with the DLL version information of the DLL on the build system.

#### 4.9.3.7 GetFileTime

    filename user_var(high dword output) user_var(low dword output)

Gets the last write time of "filename". Sets the user output variables with the high and low dwords of the timestamp on success; on failure the outputs are empty and the error flag is set.

#### 4.9.3.8 GetFileTimeLocal

    localfilename user_var(high dword output) user_var(low dword output)

This is similar to GetFileTime, only it acts on the system building the installer (it actually compiles into two StrCpy commands). Sets the two output variables with the file timestamp of the file on the build system.

#### 4.9.3.9 GetFullPathName

    [/SHORT] user_var(output) path_or_file

Assign to the user variable $x, the full path of the file specified. If the path portion of the parameter is not found, the error flag will be set and $x will be empty. If /SHORT is specified, the path is converted to the short filename form. However, if /SHORT is not specified, the path isn't converted to its long filename form. To get the long filename, call GetLongPathName using the System plug-in. Note that GetLongPathName is only available on Windows 98, Windows 2000 and above.

    StrCpy $INSTDIR $PROGRAMFILES\NSIS

    SetOutPath $INSTDIR

    GetFullPathName $0 ..

    DetailPrint $0 # will print C:\Program Files

    GetFullPathName /SHORT $0 $INSTDIR

    DetailPrint $0 # will print C:\Progra~1\NSIS

    StrCpy $0 C:\Progra~1\NSIS

    System::Call 'kernel32::GetLongPathName(t r0, t .r1, i ${NSIS_MAX_STRLEN}) i .r2'

    StrCmp $2 error +2

    StrCpy $0 $1

    DetailPrint $0 # will print C:\Program Files\NSIS, where supported

#### 4.9.3.10 GetTempFileName

    user_var(output) base_dir

Assign to the user variable $x, the name of a temporary file. The file will have been created, so you can then overwrite it with what you please. The name of the temporary file is guaranteed to be unique. If to want the temporary file to be created in another directory than the Windows temp directory, specify a base_dir. Delete the file when done with it.

    GetTempFileName $0

    File /oname=$0 something.dat

    # do something with something.dat

    Delete $0

#### 4.9.3.11 SearchPath

    user_var(output) filename

Assign to the user variable $x, the full path of the file named by the second parameter. The error flag will be set and $x will be empty if the file cannot be found. Uses SearchPath() to search the system paths for the file.

#### 4.9.3.12 SetFileAttributes

    filename attribute1|attribute2|...

Sets the file attributes of 'filename'. Valid attributes can be combined with | and are:

- NORMAL or FILE_ATTRIBUTE_NORMAL (you can use 0 to abbreviate this)
- ARCHIVE or FILE_ATTRIBUTE_ARCHIVE
- HIDDEN or FILE_ATTRIBUTE_HIDDEN
- OFFLINE or FILE_ATTRIBUTE_OFFLINE
- READONLY or FILE_ATTRIBUTE_READONLY
- SYSTEM or FILE_ATTRIBUTE_SYSTEM
- TEMPORARY or FILE_ATTRIBUTE_TEMPORARY

The error flag will be set if the file's attributes cannot be set (i.e. the file doesn't exist, or you don't have the right permissions). You can only set attributes. It's not possible to unset them. If you want to remove an attribute use NORMAL. This way all attributes are erased. This command doesn't support wildcards.

#### 4.9.3.13 RegDLL

    dllfile [entrypoint_name]

Loads the specified DLL and calls DllRegisterServer (or entrypoint_name if specified). The error flag is set if an error occurs (i.e. it can't load the DLL, initialize OLE, find the entry point, or the function returned anything other than ERROR_SUCCESS (=0)).

Use SetOutPath to set the current directory for DLLs that depend on other DLLs that are now in the path or in the Windows directory. For example, if foo.dll depends on bar.dll which is located in $INSTDIR use:

     SetOutPath $INSTDIR

     RegDLL $INSTDIR\foo.dll

#### 4.9.3.14 UnRegDLL

    dllfile

Loads the specified DLL and calls DllUnregisterServer. The error flag is set if an error occurs (i.e. it can't load the DLL, initialize OLE, find the entry point, or the function returned anything other than ERROR_SUCCESS (=0)).

### 4.9.4 Flow Control Instructions

#### 4.9.4.1 Abort

    user_message

Cancels the install, stops execution of script, and displays user_message in the status display. Note: you can use this from Callback functions to do special things. Page callbacks also uses Abort for special purposes.

    Abort

    Abort "can't install"

#### 4.9.4.2 Call

    function_name | :label_name | user_var(input)

Calls the function named function_name, the label named label_name, or a variable that specifies an address. An address is returned by GetCurrentAddress, GetFunctionAddress or GetLabelAddress. A call returns when it encounters a Return instruction. Sections and functions are automatically ended with a Return instruction. Uninstall functions cannot be called from installer functions and sections, and vice-versa.

    Function func

      Call :label

      DetailPrint "#1: This will only appear 1 time."

    label:

      DetailPrint "#2: This will appear before and after message #1."

      Call :.global_label

    FunctionEnd

    Section

      Call func

      Return

    .global_label:

      DetailPrint "#3: The global label was called"

    SectionEnd

#### 4.9.4.3 ClearErrors

Clears the error flag.

    ClearErrors

    IfErrors 0 +2

      MessageBox MB_OK "this message box will never show"

#### 4.9.4.4 GetCurrentAddress

    user_var(output)

Gets the address of the current instruction (the GetCurrentAddress) and stores it in the output user variable. This user variable then can be passed to Call or Goto.

    Function func

      DetailPrint "function"

      IntOp $0 $0 + 2

      Call $0

      DetailPrint "function end"

    FunctionEnd

    Section

      DetailPrint "section"

      DetailPrint "section"

      GetCurrentAddress $0

      Goto callFunc

      DetailPrint "back to section"

      Return

    callFunc:

      Call func

      DetailPrint "section end"

    SectionEnd

#### 4.9.4.5 GetFunctionAddress

    user_var(output) function_name

Gets the address of the function and stores it in the output user variable. This user variable then can be passed to Call or Goto. Note that if you Goto an address which is the output of GetFunctionAddress, your function will never be returned to (when the function you Goto'd to returns, you return instantly).

    Function func

      DetailPrint "function"

    FunctionEnd

    Section

      GetFunctionAddress $0 func

      Call $0

    SectionEnd

#### 4.9.4.6 GetLabelAddress

    user_var(output) label

Gets the address of the label and stores it in the output user variable. This user variable then can be passed to Call or Goto. Note that you may only call this with labels accessible from your function, but you can call it from anywhere (which is potentially dangerous). Note that if you Call the output of GetLabelAddress, code will be executed until it Return's (explicitly or implicitly at the end of a function), and then you will be returned to the statement after the Call.

    label:

    DetailPrint "label"

    GetLabelAddress $0 label

    IntOp $0 $0 + 4

    Goto $0

    DetailPrint "done"

#### 4.9.4.7 Goto

    label_to_jump_to | +offset| -offset| user_var(target)

If label is specified, goto the label 'label_to_jump_to:'.

If +offset or -offset is specified, jump is relative by offset instructions. Goto +1 goes to the next instruction, Goto -1 goes to the previous instruction, etc.

If a user variable is specified, jumps to absolute address (generally you will want to get this value from a function like GetLabelAddress). Compiler flag commands and SectionIn aren't instructions so jumping over them has no effect.

    Goto label

    Goto +2

    Goto -2

    Goto $0

#### 4.9.4.8 IfAbort

    label_to_goto_if_abort [label_to_goto_if_no_abort]

If abort is called it will "return" true. This can happen if the user chose abort on a file that failed to create (or overwrite) or if the user aborted by hand. This function can only be called from the leave function of the instfiles page.

    Page instfiles "" "" instfilesLeave

    Function instfilesLeave

      IfAbort 0 +2

        MessageBox MB_OK "user aborted"

    FunctionEnd

#### 4.9.4.9 IfErrors

    jumpto_iferror [jumpto_ifnoerror]

Checks and clears the error flag, and if it is set, it will goto jumpto_iferror, otherwise it will goto jumpto_ifnoerror. The error flag is set by other instructions when a recoverable error (such as trying to delete a file that is in use) occurs.

    ClearErrors

    File file.dat

    IfErrors 0 +2

      Call ErrorHandler

#### 4.9.4.10 IfFileExists

    file_to_check_for jump_if_present [jump_otherwise]

Checks for existence of file(s) file_to_check_for (which can be a wildcard, or a directory), and Gotos jump_if_present if the file exists, otherwise Gotos jump_otherwise. If you want to check to see if a file is a directory, use IfFileExists DIRECTORY\*.*

    IfFileExists $WINDIR\notepad.exe 0 +2

      MessageBox MB_OK "notepad is installed"

#### 4.9.4.11 IfRebootFlag

    jump_if_set [jump_if_not_set]

Checks the reboot flag, and jumps to jump_if_set if the reboot flag is set, otherwise jumps to jump_if_not_set. The reboot flag can be set by Delete and Rename, or manually with SetRebootFlag.

    IfRebootFlag 0 noreboot

      MessageBox MB_YESNO "A reboot is required to finish the installation. Do you wish to reboot now?" IDNO noreboot

        Reboot

    noreboot:

#### 4.9.4.12 IfSilent

    jump_if_silent [jump_if_not]

Checks the silent flag, and jumps to jump_if_silent if the installer is silent, otherwise jumps to jump_if_not. The silent flag can be set by SilentInstall, SilentUninstall, SetSilent and by the user passing /S on the command line.

    IfSilent +2

      ExecWait '"$INSTDIR\nonsilentprogram.exe"'

#### 4.9.4.13 IntCmp

    val1 val2 jump_if_equal [jump_if_val1_less] [jump_if_val1_more]

Compares two integers val1 and val2. If val1 and val2 are equal, Gotos jump_if_equal, otherwise if val1 < val2, Gotos jump_if_val1_less, otherwise if val1 > val2, Gotos jump_if_val1_more.

    IntCmp $0 5 is5 lessthan5 morethan5

    is5:

      DetailPrint "$$0 == 5"

      Goto done

    lessthan5:

      DetailPrint "$$0 < 5"

      Goto done

    morethan5:

      DetailPrint "$$0 > 5"

      Goto done

    done:

#### 4.9.4.14 IntCmpU

    val1 val2 jump_if_equal [jump_if_val1_less] [jump_if_val1_more]

Compares two unsigned integers val1 and val2. If val1 and val2 are equal, Gotos jump_if_equal, otherwise if val1 < val2, Gotos jump_if_val1_less, otherwise if val1 > val2, Gotos jump_if_val1_more. Performs the comparison as unsigned integers.

#### 4.9.4.15 MessageBox

    mb_option_list messagebox_text [/SD return] [return_check jumpto] [return_check_2 jumpto_2]

Displays a MessageBox containing the text "messagebox_text". mb_option_list must be one or more of the following, delimited by |s (e.g. MB_YESNO|MB_ICONSTOP).

- MB_OK - Display with an OK button
- MB_OKCANCEL - Display with an OK and a cancel button
- MB_ABORTRETRYIGNORE - Display with abort, retry, ignore buttons
- MB_RETRYCANCEL - Display with retry and cancel buttons
- MB_YESNO - Display with yes and no buttons
- MB_YESNOCANCEL - Display with yes, no, cancel buttons
- MB_ICONEXCLAMATION - Display with exclamation icon
- MB_ICONINFORMATION - Display with information icon
- MB_ICONQUESTION - Display with question mark icon
- MB_ICONSTOP - Display with stop icon
- MB_USERICON - Display with installer's icon
- MB_TOPMOST - Make messagebox topmost
- MB_SETFOREGROUND - Set foreground
- MB_RIGHT - Right align text
- MB_RTLREADING - RTL reading order
- MB_DEFBUTTON1 - Button 1 is default
- MB_DEFBUTTON2 - Button 2 is default
- MB_DEFBUTTON3 - Button 3 is default
- MB_DEFBUTTON4 - Button 4 is default

Return_check can be 0 (or empty, or left off), or one of the following:

- IDABORT - Abort button
- IDCANCEL - Cancel button
- IDIGNORE - Ignore button
- IDNO - No button
- IDOK - OK button
- IDRETRY - Retry button
- IDYES - Yes button

If the return value of the MessageBox is return_check, the installer will Goto jumpto.

Use the /SD parameter with one of the return_check values above to specify the option that will be used when the installer is silent. See section 4.12 for more information.

    MessageBox MB_OK "simple message box"

    MessageBox MB_YESNO "is it true?" IDYES true IDNO false

    true:

      DetailPrint "it's true!"

      Goto next

    false:

      DetailPrint "it's false"

    next:

    MessageBox MB_YESNO "is it true? (defaults to yes on silent installations)" /SD IDYES IDNO false2

      DetailPrint "it's true (or silent)!"

      Goto next2

    false2:

      DetailPrint "it's false"

    next2:

#### 4.9.4.16 Return

Returns from a function or section.

    Function func

      StrCmp $0 "return now" 0 +2

        Return

      # do stuff

    FunctionEnd

    Section

      Call func

      ;"Return" will return here

    SectionEnd

#### 4.9.4.17 Quit

Causes the installer to exit as soon as possible. After Quit is called, the installer will exit (no callback functions will get a chance to run).

#### 4.9.4.18 SetErrors

Sets the error flag.

    SetErrors

    IfErrors 0 +2

      MessageBox MB_OK "this message box will always show"

#### 4.9.4.19 StrCmp

    str1 str2 jump_if_equal [jump_if_not_equal]

Compares (case insensitively) str1 to str2. If str1 and str2 are equal, Gotos jump_if_equal, otherwise Gotos jump_if_not_equal.

    StrCmp $0 "a string" 0 +3

      DetailPrint '$$0 == "a string"'

      Goto +2

      DetailPrint '$$0 != "a string"'

#### 4.9.4.20 StrCmpS

    str1 str2 jump_if_equal [jump_if_not_equal]

Same as StrCmp, but case sensitive.

### 4.9.5 File Instructions

#### 4.9.5.1 FileClose

    handle

Closes a file handle opened with FileOpen.

#### 4.9.5.2 FileOpen

    user_var(handle output) filename openmode

Opens a file named "filename", and sets the handle output variable with the handle. The openmode should be one of "r" (read) "w" (write, all contents of file are destroyed) or "a" (append, meaning opened for both read and write, contents preserved). In all open modes, the file pointer is placed at the beginning of the file. If the file cannot be opened, the handle output is set to empty, and the error flag is set.

If no absolute path is specified the current folder will be used. The current folder is the folder set using the last SetOutPath instruction. If you have not used SetOutPath the current folder is $EXEDIR.

    FileOpen $0 $INSTDIR\file.dat r

    FileClose $0

#### 4.9.5.3 FileRead

    handle user_var(output) [maxlen]

Reads a string from a file opened with FileOpen. The string is read until either a newline (or carriage return newline pair) occurs, or until a null byte is read, or until maxlen is met (if specified). By default, strings are limited to 1024 characters (a special build with larger NSIS_MAX_STRLEN can be compiled or downloaded). If the end of file is read and no more data is available, the output string will be empty, and the error flag will be set.

    ClearErrors

    FileOpen $0 $INSTDIR\file.dat r

    IfErrors done

    FileRead $0 $1

    DetailPrint $1

    FileClose $0

    done:

#### 4.9.5.4 FileReadByte

    handle user_var(output)

Reads a byte from a file opened with FileOpen. The byte is stored in the output as an integer (0-255). If the end of file is read and no more data is available, the output will be empty, and the error flag will be set.

    ClearErrors

    FileOpen $0 $INSTDIR\file.dat r

    IfErrors done

    FileReadByte $0 $1

    FileReadByte $0 $2

    DetailPrint "$1 $2"

    FileClose $0

    done:

#### 4.9.5.5 FileSeek

    handle offset [mode] [user_var(new position)]

Seeks a file opened with FileOpen. If mode is omitted or specified as SET, the file is positioned to "offset", relative to the beginning of the file. If mode is specified as CUR, then the file is positioned to "offset", relative to the current file position. If mode is specified as END, then the file is positioned to "offset", relative to the end of the file. If the final parameter "new position" is specified, the new file position will be stored to that variable.

    ClearErrors

    FileOpen $0 $INSTDIR\file.dat r

    IfErrors done

    FileSeek $0 -5 END

    FileRead $0 $1

    DetailPrint $1

    FileClose $0

    done:

#### 4.9.5.6 FileWrite

    handle string

Writes a string to a file opened with FileOpen. If an error occurs writing, the error flag will be set.

    ClearErrors

    FileOpen $0 $INSTDIR\file.dat w

    IfErrors done

    FileWrite $0 "some text"

    FileClose $0

    done:

#### 4.9.5.7 FileWriteByte

    handle string

Writes the integer interpretation of 'string' to a file opened with FileOpen. Of course you can enter the integer value directly. The following code writes a "Carriage Return / Line Feed" - Enter to the file.

    FileWriteByte file_handle "13"

    FileWriteByte file_handle "10"

If an error occurs while writing, the error flag will be set. Note that the low byte of the integer is used, i.e. writing 256 is the same as writing 0, etc.

#### 4.9.5.8 FindClose

    handle

Closes a search opened with FindFirst.

#### 4.9.5.9 FindFirst

    user_var(handle output) user_var(filename output) filespec

Performs a search for 'filespec', placing the first file found in filename_output (a user variable). It also puts the handle of the search into handle_output (also a user variable). If no files are found, both outputs are set to empty, and the error flag is set. Best used with FindNext and FindClose. Note that the filename output is without path.

    FindFirst $0 $1 $INSTDIR\*.txt

    loop:

      StrCmp $1 "" done

      DetailPrint $1

      FindNext $0 $1

      Goto loop

    done:

#### 4.9.5.10 FindNext

    handle user_var(filename_output)

Continues a search began with FindFirst. handle should be the handle_output_variable returned by FindFirst. If the search is completed (there are no more files), filename_output is set to empty, and the error flag is set. Note that the filename output is without path.

### 4.9.6 Uninstaller Instructions

#### 4.9.6.1 WriteUninstaller

    [Path\]exename.exe

Writes the uninstaller to the filename (and optionally path) specified. Only valid from within an install section or function, and requires that you have an uninstall section in your script. See also Uninstall configuration. You can call this one or more times to write out one or more copies of the uninstaller.

    WriteUninstaller $INSTDIR\uninstaller.exe

### 4.9.7 Miscellaneous Instructions

#### 4.9.7.1 GetErrorLevel

    user_var(error level output)

Returns the last error level set by SetErrorLevel or -1 if it was never used.

    GetErrorLevel $0

    IntOp $0 $0 + 1

    SetErrorLevel $0

#### 4.9.7.2 GetInstDirError

    user_var(error output)

Use in the leave function of a directory page. Reads the flag set if 'DirVerify leave' is used. Possible values:

0: No error

1: Invalid installation directory

2: Not enough space on installation drive

    !include LogicLib.nsh

    PageEx directory

      DirVerify leave

      PageCallbacks "" "" dirLeave

    PageExEnd

    Function dirLeave

      GetInstDirError $0

      ${Switch} $0

        ${Case} 0

          MessageBox MB_OK "valid installation directory"

          ${Break}

        ${Case} 1

          MessageBox MB_OK "invalid installation directory!"

          Abort

          ${Break}

        ${Case} 2

          MessageBox MB_OK "not enough free space!"

          Abort

          ${Break}

      ${EndSwitch}

    FunctionEnd

#### 4.9.7.3 InitPluginsDir

Initializes the plug-ins dir ($PLUGINSDIR) if not already initialized.

    InitPluginsDir

    File /oname=$PLUGINSDIR\image.bmp image.bmp

#### 4.9.7.4 Nop

Does nothing.

#### 4.9.7.5 SetErrorLevel

    error_level

Sets the error level of the installer or uninstaller to error_level. See Error Levels for more information.

    IfRebootFlag 0 +2

      SetErrorLevel 4

#### 4.9.7.6 SetRegView

    32|64|lastused

Sets the registry view affected by registry commands. On Windows x64 there are two views. One for 32-bit applications and one for x64 applications. By default, 32-bit applications running on x64 systems under WOW64 have access only to the 32-bit view. Using `SetRegView 64` allows the installer to access keys in the x64 view of the registry.

Affects DeleteRegKey, DeleteRegValue, EnumRegKey, EnumRegValue, ReadRegDWORD, ReadRegStr, WriteRegBin, WriteRegDWORD, WriteRegStr and WriteRegExpandStr.

Does not affect InstallDirRegKey. Instead, the registry can be read using ReadRegStr in .onInit.

    SetRegView 32

    ReadRegStr $0 HKLM Software\Microsoft\Windows\CurrentVersion ProgramFilesDir

    DetailPrit $0 # prints C:\Program Files (x86)

    SetRegView 64

    ReadRegStr $0 HKLM Software\Microsoft\Windows\CurrentVersion ProgramFilesDir

    DetailPrit $0 # prints C:\Program Files

    Function .onInit

      SetRegView 64

      ReadRegStr $INSTDIR HKLM Software\NSIS ""

      SetRegView 32

    FunctionEnd

#### 4.9.7.7 SetShellVarContext

    current|all

Sets the context of $SMPROGRAMS and other shell folders. If set to 'current' (the default), the current user's shell folders are used. If set to 'all', the 'all users' shell folder is used. The all users folder may not be supported on all OSes. If the all users folder is not found, the current user folder will be used. Please take into consideration that a "normal user" has no rights to write in the all users area. Only admins have full access rights to the all users area. You can check this by using the UserInfo plug-in. See Contrib\UserInfo\UserInfo.nsi for an example.

Note that, if used in installer code, this will only affect the installer, and if used in uninstaller code, this will only affect the uninstaller. To affect both, it needs to be used in both.

    SetShellVarContext current

    StrCpy $0 $DESKTOP

    SetShellVarContext all

    StrCpy $1 $DESKTOP

    MessageBox MB_OK $0$\n$1

#### 4.9.7.8 Sleep

    sleeptime_in_ms

Pauses execution in the installer for sleeptime_in_ms milliseconds. sleeptime_in_ms can be a variable, e.g. "$0" or a number, i.e. "666".

    DetailPrint "sleeping..."

    Sleep 3000

    DetailPrint "back to work"

### 4.9.8 String Manipulation Instructions

#### 4.9.8.1 StrCpy

    user_var(destination) str [maxlen] [start_offset]

Sets the user variable $x with str. Note that str can contain other variables, or the user variable being set (concatenating strings this way is possible, etc). If maxlen is specified, the string will be a maximum of maxlen characters (if maxlen is negative, the string will be truncated abs(maxlen) characters from the end). If start_offset is specified, the source is offset by it (if start_offset is negative, it will start abs(start_offset) from the end of the string).

    StrCpy $0 "a string" # = "a string"

    StrCpy $0 "a string" 3 # = "a s"

    StrCpy $0 "a string" -1 # = "a strin"

    StrCpy $0 "a string" "" 2 # = "string"

    StrCpy $0 "a string" "" -3 # = "ing"

    StrCpy $0 "a string" 3 -4 # = "rin"

#### 4.9.8.2 StrLen

    user_var(length output) str

Sets user variable $x with the length of str.

    StrLen $0 "123456" # = 6

### 4.9.9 Stack Support

#### 4.9.9.1 Exch

    [user_var | stack_index]

When no parameter is specified, exchanges the top two elements of the stack. When a parameter is specified and is a user variable, exchanges the top element of the stack with the parameter. When a parameter is specified and is a positive integer, Exch will swap the item on the top of the stack with the item that is specified by the offset from the top of the stack in the parameter. If there are not enough items on the stack to accomplish the exchange, a fatal error will occur (to help you debug your code :).

    Push 1

    Push 2

    Exch

    Pop $0 # = 1

    Push 1

    Push 2

    Push 3

    Exch 2

    Pop $0 # = 1

    StrCpy $0 1

    Push 2

    Exch $0 # = 2

    Pop $1 # = 1

#### 4.9.9.2 Pop

    user_var(out)

Pops a string off of the stack into user variable $x. If the stack is empty, the error flag will be set.

    Push 1

    Pop $0 # = 1

#### 4.9.9.3 Push

    string

Pushes a string onto the stack. The string can then be Popped off of the stack.

    Push "a string"

### 4.9.10 Integer Support

#### 4.9.10.1 IntFmt

    user_var(output) format numberstring

Formats the number in "numberstring" using the format "format", and sets the output to user variable $x. Example format strings include "%08X" "%u"

    IntFmt $0 "0x%08X" 195948557

    IntFmt $0 "%c" 0x41

#### 4.9.10.2 IntOp

    user_var(output) value1 OP [value2]

Combines value1 and (depending on OP) value2 into the specified user variable (`user_var`). OP is defined as one of the following:

- + ADDs value1 and value2
- - SUBTRACTs value2 from value1
- * MULTIPLIEs value1 and value2
- / DIVIDEs value1 by value2
- % MODULUSs value1 by value2
- | BINARY ORs value1 and value2
- & BINARY ANDs value1 and value2
- ^ BINARY XORs value1 and value2
- >> RIGHT SHIFTs value1 by value2
- << LEFT SHIFTs value1 by value2
- ~ BITWISE NEGATEs value1 (i.e. 7 becomes 4294967288)
- ! LOGICALLY NEGATEs value1 (i.e. 7 becomes 0)
- || LOGICALLY ORs value1 and value2
- && LOGICALLY ANDs value1 and value2

    IntOp $0 1 + 1

    IntOp $0 $0 + 1

    IntOp $0 $0 << 2

    IntOp $0 $0 ~

    IntOp $0 $0 & 0xF

### 4.9.11 Reboot Instructions

#### 4.9.11.1 Reboot

Reboots the computer. Be careful with this one. If it fails, .onRebootFailed is called. In any case, this instruction never returns, just like Quit.

    MessageBox MB_YESNO|MB_ICONQUESTION "Do you wish to reboot the system?" IDNO +2

      Reboot

#### 4.9.11.2 SetRebootFlag

    true|false

Sets the reboot flag to either true or false. The flag's value can be read using IfRebootFlag.

    SetRebootFlag true

    IfRebootFlag 0 +2

      MessageBox MB_OK "this message box will always show"

### 4.9.12 Install Logging Instructions

#### 4.9.12.1 LogSet

    on|off

Sets whether install logging to $INSTDIR\install.log will happen. $INSTDIR must have a value before you call this function or it will not work. Note that the NSIS_CONFIG_LOG build setting must be set (`scons NSIS_CONFIG_LOG=yes`) on compile time (it is not by default) to support this. See Building NSIS for more information about recompiling NSIS.

#### 4.9.12.2 LogText

    text

If installer logging is enabled, inserts text "text" into the log file.

    IfFileExists $WINDIR\notepad.exe 0 +2

      LogText "$$WINDIR\notepad.exe exists"

### 4.9.13 Section Management

#### 4.9.13.1 SectionSetFlags

    section_index section_flags

Sets the section's flags. The flag is a 32 bit integer. The first bit (lowest) represents whether the section is currently selected, the second bit represents whether the section is a section group (don't modify this unless you really know what you are doing), the third bit represents whether the section is a section group end (again, don't modify), the fourth bit represents whether the section is shown in bold or not, the fifth bit represents whether the section is read-only, the sixth bit represents whether the section group is to be automatically expanded, the seventh bit is set for section groups which are partially selected, the eighth bit is internally used for partially selected section group toggling and the ninth bit is used for reflecting section name changes. The error flag will be set if an out of range section is specified.

Each flag has a name, prefixed with `SF_`:

    !define SF_SELECTED   1

    !define SF_SECGRP     2

    !define SF_SECGRPEND  4

    !define SF_BOLD       8

    !define SF_RO         16

    !define SF_EXPAND     32

    !define SF_PSELECTED  64

For an example of usage please see the one-section.nsi example.

For more useful macros and definitions, see Include\Sections.nsh.

    Section test test_section_id

    SectionEnd

    Function .onInit

      # set section 'test' as selected and read-only

      IntOp $0 ${SF_SELECTED} | ${SF_RO}

      SectionSetFlags ${test_section_id} $0

    FunctionEnd

#### 4.9.13.2 SectionGetFlags

    section_index user_var(output)

Retrieves the section's flags. See above for a description of the flag. The error flag will be set if an out of range section is specified.

    Section test test_section_id

    SectionEnd

    Function .onSelChange

      # keep section 'test' selected

      SectionGetFlags ${test_section_id} $0

      IntOp $0 $0 | ${SF_SELECTED}

      SectionSetFlags ${test_section_id} $0

    FunctionEnd

#### 4.9.13.3 SectionSetText

    section_index section_text

Sets the description for the section section_index. If the text is set to "" then the section will be hidden. The error flag will be set if an out of range section is specified.

    Section "" test_section_id

    SectionEnd

    Function .onInit

      # change section's name to $WINDIR

      SectionSetText ${test_section_id} $WINDIR

    FunctionEnd

#### 4.9.13.4 SectionGetText

    section_index user_var(output)

Stores the text description of the section section_index into the output. If the section is hidden, stores an empty string. The error flag will be set if an out of range section is specified.

    Section test test_section_id

    SectionEnd

    Function .onInit

      # append $WINDIR to section's name

      SectionGetText ${test_section_id} $0

      StrCpy $0 "$0 - $WINDIR"

      SectionSetText ${test_section_id} $0

    FunctionEnd

#### 4.9.13.5 SectionSetInstTypes

    section_index inst_types

Sets the install types the section specified by section_index defaults to the enabled state in. Note that the section index starts with zero. Every bit of inst_types is a flag that tells if the section is in that install type or not. For example, if you have 3 install types and you want the first section to be included in install types 1 and 3, then the command should look like this:

    SectionSetInstTypes 0 5

because the binary value for 5 is "00000101". The error flag will be set if the section index specified is out of range.

    Section test test_section_id

    SectionEnd

    Function .onInit

      # associate section 'test' with installation types 3 and 4

      SectionSetInstTypes ${test_section_id} 12

    FunctionEnd

#### 4.9.13.6 SectionGetInstTypes

    section_index user_var(output)

Retrieves the install types flags array of a section. See above explanation about SectionSetInstTypes for a description of how to deal with the output. The error flag will be set if the section index specified is out of range.

    Section test test_section_id

    SectionEnd

    Function .onInit

      # associate section 'test' with installation types 5, on top of its existing associations

      SectionGetInstTypes ${test_section_id} $0

      IntOp $0 $0 | 16

      SectionSetInstTypes ${test_section_id} $0

    FunctionEnd

#### 4.9.13.7 SectionSetSize

    section_index new_size

Sets the Size of the section specified by section_index. Note that the Index starts with Zero. The Value for Size must be entered in KiloByte and supports only whole numbers.

    Section test test_section_id

    SectionEnd

    Function .onInit

      # set required size of section 'test' to 100 bytes

      SectionSetSize ${test_section_id} 100

    FunctionEnd

#### 4.9.13.8 SectionGetSize

    section_index user_var

Gets the Size of the section specified by section_index and stores the value in the given User Variable. Note that the Index starts with Zero.

    Section test test_section_id

    SectionEnd

    Function .onInit

      # increase required size of section 'test' by 100 bytes

      SectionGetSize ${test_section_id} $0

      IntOp $0 $0 + 100

      SectionSetSize ${test_section_id} $0

    FunctionEnd

#### 4.9.13.9 SetCurInstType

    inst_type_idx

Sets the current InstType. inst_type_idx should be between 0 and 31. The Error Flag is not set if an out of range InstType was used.

#### 4.9.13.10 GetCurInstType

    user_var

Get the current InstType and stores it in user_var. If the first install type is selected, 0 will be put in user_var. If the second install type is selected, 1 will be put in user_var, and so on. The value of ${NSIS_MAX_INST_TYPES} (32 by default) means that the custom install type was selected.

#### 4.9.13.11 InstTypeSetText

    inst_type_idx text

Sets the Text of the specified InstType. If the Text is empty than the InstType is removed. By using a previously unused inst_type_idx number you can create new InstTypes. To add/remove Sections to this new InstType see SectionSetInstTypes. Unlike SectionIn the index is zero based, which means the first install type's index is 0.

    InstType a

    InstType b

    Function .onInit

      # set first installation type's name to $WINDIR

      InstTypeSetText 0 $WINDIR

      # set second installation type's name to $TEMP

      InstTypeSetText 1 $TEMP

    FunctionEnd

#### 4.9.13.12 InstTypeGetText

    inst_type_idx user_var

Gets the Text of the specified InstType.

    InstType a

    InstType b

    Function .onInit

      InstTypeGetText 0 $0

      DetailPrint $0 # prints 'a'

      InstTypeGetText 1 $0

      DetailPrint $0 # prints 'b'

    FunctionEnd

### 4.9.14 User Interface Instructions

#### 4.9.14.1 BringToFront

Makes the installer window visible and brings it to the top of the window list. If an application was executed that shows itself in front of the installer, a BringToFront would bring the installer back in focus.

Recent Windows versions restrict the setting of foreground windows. If the user is working with another application during installation, the user may be notified using a different method.

#### 4.9.14.2 CreateFont

    user_var(handle output) face_name [height] [weight] [/ITALIC] [/UNDERLINE] [/STRIKE]

Creates a font and puts its handle into user_var. For more information about the different parameters have a look at MSDN's page about the Win32 API function CreateFont().

You can get the current font used by NSIS using the ^Font and ^FontSize LangStrings.

    !include WinMessages.nsh

    GetDlgItem $0 $HWNDPARENT 1

    CreateFont $1 "Times New Roman" "7" "700" /UNDERLINE

    SendMessage $0 ${WM_SETFONT} $1 1

#### 4.9.14.3 DetailPrint

    user_message

Adds the string "user_message" to the details view of the installer.

    DetailPrint "this message will show on the installation window"

#### 4.9.14.4 EnableWindow

    hwnd (1|0)

Enables or disables mouse and keyboard input to the specified window or control. Possible states are 0 (disabled) or 1 (enabled).

    GetDlgItem $0 $HWNDPARENT 1

    EnableWindow $0 0

    Sleep 1000

    EnableWindow $0 1

#### 4.9.14.5 FindWindow

    user_var(hwnd output) windowclass [windowtitle] [windowparent] [childafter]

Searches for a window. Behaves like the win32 FindWindowEx(). Searches by windowclass (and/or windowtitle if specified). If windowparent or childafter are specified, the search will be restricted as such. If windowclass or windowtitle is specified as "", they will not be used for the search. If the window is not found, the user variable returned is 0. To accomplish old-style FindWindow behavior, use FindWindow with SendMessage.

    FindWindow $0 "#32770" "" $HWNDPARENT

    FindWindow $0 "my window class" "my window title"

#### 4.9.14.6 GetDlgItem

    user_var(output) dialog item_id

Retrieves the handle of a control identified by item_id in the specified dialog box dialog. If you want to get the handle of a control on the inner dialog, first use FindWindow user_var(output) "#32770" "" $HWNDPARENT to get the handle of the inner dialog.

    GetDlgItem $0 $HWNDPARENT 1 # next/install button

#### 4.9.14.7 HideWindow

Hides the installer.

#### 4.9.14.8 IsWindow

    HWND jump_if_window [jump_if_not_window]

If HWND is a window, Gotos jump_if_window, otherwise, Gotos jump_if_not_window (if specified).

    GetDlgItem $0 $HWNDPARENT 1

    IsWindow $0 0 +3

      MessageBox MB_OK "found a window"

      Goto +2

      MessageBox MB_OK "no window"

#### 4.9.14.9 LockWindow

    on|off

LockWindow on prevents the main window from redrawing itself upon changes. When LockWindow off is used, all controls that weren't redrawn since LockWindow on will be redrawn. This makes the pages flickering look nicer because now it flickers a group of controls at the same time, instead of one control at a time. The individual control flickering is more noticeable on old computers.

#### 4.9.14.10 SendMessage

    HWND msg wparam lparam [user_var(return value)] [/TIMEOUT=time_in_ms]

Sends a message to HWND. If a user variable $x is specified as the last parameter (or one before the last if you use /TIMEOUT), the return value of SendMessage will be stored to it. Note that when specifying 'msg' you must just use the integer value of the message. If you wish to send strings use "STR:a string" as wParam or lParam where needed.

- WM_CLOSE 16
- WM_COMMAND 273
- WM_USER 1024

Include WinMessages.nsh to have all of Windows messages defined in your script.

To send a string param, put STR: before the parameter, for example: "STR:Some string".

Use /TIMEOUT=time_in_ms to specify the duration, in milliseconds, of the time-out period.

    !include WinMessages.nsh

    FindWindow $0 "Winamp v1.x"

    SendMessage $0 ${WM_CLOSE} 0 0

#### 4.9.14.11 SetAutoClose

    true|false

Overrides the default auto window-closing flag (specified for the installer using AutoCloseWindow, and false for the uninstaller). Specify 'true' to have the install window immediately disappear after the install has completed, or 'false' to make it require a manual close.

#### 4.9.14.12 SetBrandingImage

    [/IMGID=item_id_in_dialog] [/RESIZETOFIT] path_to_bitmap_file.bmp

Sets the current bitmap file displayed as the branding image. If no IMGID is specified, the first image control found will be used, or the image control created by AddBrandingImage. Note that this bitmap must be present on the user's machine. Use File first to put it there. If /RESIZETOFIT is specified the image will be automatically resized (very poorly) to the image control size. If you used AddBrandingImage you can get this size, by compiling your script and watching for AddBrandingImage output, it will tell you the size. SetBrandingImage will not work when called from .onInit!

#### 4.9.14.13 SetDetailsView

    show|hide

Shows or hides the details, depending on which parameter you pass. Overrides the default details view, which is set via ShowInstDetails.

#### 4.9.14.14 SetDetailsPrint

    none|listonly|textonly|both|lastused

Sets mode at which commands print their status. None has commands be quiet, listonly has status text only added to the listbox, textonly has status text only printed to the status bar, and both enables both (the default). For extracting many small files, textonly is recommended (especially on win9x with smooth scrolling enabled).

    SetDetailsPrint none

    File "secret file.dat"

    SetDetailsPrint both

#### 4.9.14.15 SetCtlColors

    hwnd [/BRANDING] [text_color] [transparent|bg_color]

Sets a background color and the text color for a static control, edit control, button or a dialog. text_color and bg_color don't accept variables. Use GetDlgItem to get the handle (HWND) of the control. To make the control transparent specify "transparent" as the background color value. You can also specify /BRANDING with or without text color and background color to make the control completely gray (or any other color you choose). This is used by the branding text control in the MUI.

    FindWindow $0 "#32770" "" $HWNDPARENT

    GetDlgItem $0 $0 1006

    SetCtlColors $0 0xFF0000 0x00FF00

Warning: setting the background color of check boxes to "transparent" may not function properly when using `XPStlye` `on`. The background may be completely black, instead of transparent, when using certain Windows themes.

#### 4.9.14.16 SetSilent

    silent | normal

Sets the installer to silent mode or normal mode. See SilentInstall for more information about silent installations. Can only be used in .onInit.

#### 4.9.14.17 ShowWindow

    hwnd show_state

Sets the visibility of a window. Possible show_states are the same as Windows ShowWindow function. SW_* constants are defined in Include\WinMessages.nsh.

    !include WinMessages.nsh

    GetDlgItem $0 $HWNDPARENT 1

    ShowWindow $0 ${SW_HIDE}

    Sleep 1000

    ShowWindow $0 ${SW_SHOW}

### 4.9.15 Multiple Languages Instructions

#### 4.9.15.1 LoadLanguageFile

    language_file.nlf

Loads a language file for the construction of a language table. All of the language files that come with NSIS are in Contrib\Language Files

After you have inserted the language file ${LANG_langfile} will be defined as the language id (for example, ${LANG_ENGLISH} will be defined as 1033). Use it with LangString, LicenseLangString, LangDLL and VIAddVersionKey.

#### 4.9.15.2 LangString

    name language_id string

Defines a multilingual string. This means its value may be different (or not, it's up to you) for every language. It allows you to easily make your installer multilingual without the need to add massive switches to the script.

Each language string has a name that identifies it and a value for each language used by the installer. They can be used in any runtime string in the script. To use a language string all you need to add to the string is $(LangString_name_here) where you want the LangString to be inserted.

Notes:

- Unlike defines that use curly braces - {}, language strings use parenthesis - ().
- If you change the language in the .onInit function, note that language strings in .onInit will still use the detected language based on the user's default Windows language, because the language is initialized after .onInit.
- Always set language strings for every language in your script.
- If you set the language ID to 0 the last used language by LangString or LoadLanguageFile will be used.

Example of usage:

     LangString message ${LANG_ENGLISH} "English message"

     LangString message ${LANG_FRENCH} "French message"

     LangString message ${LANG_KOREAN} "Korean message"

     MessageBox MB_OK "A translated message: $(message)"

#### 4.9.15.3 LicenseLangString

    name language_id license_path

Does the same as LangString only it loads the string from a text/RTF file and defines a special LangString that can be used only by LicenseData.

    LicenseLangString license ${LANG_ENGLISH} license-english.txt

    LicenseLangString license ${LANG_FRENCH} license-french.txt

    LicenseLangString license ${LANG_GERMAN} license-german.txt

    LicenseData $(license)

Previous | Contents | Next